LTSpice Model erstellen

Hallo,

du öffnest die PSpicedatei mit nem Texteditor. Das Model kannst du kann komplett im die LTSpicedatei (zB bei Transistoren standard.bjt) einfügen. Dann muss du nach dem "npn" bzw "pnp" eine Klammer auf machen, und am ende des Models wieder zu.

* MODEL FORMAT: PSpice .MODEL Qmjl4281a npn +IS=9.94641e-11 BF=191.836 NF=1.11524 VAF=24.7449 +IKF=5.75399 ISE=6.4507e-12 NE=3.39407 BR=4.35182 +NR=1.1764 VAR=4.25175 IKR=6.61715 ISC=3.89999e-13 +NC=3.99 RB=4.37715 IRB=0.00966879 RBM=1e-15 +RE=0.00608852 RC=0.0434329 XTB=0.661303 XTI=1.00355 +EG=1.05 CJE=9.04931e-09 VJE=0.99 MJE=0.844324 +TF=1.6665e-09 XTF=1000 VTF=17023.9 ITF=152.472 +CJC=8.80163e-10 VJC=0.942802 MJC=0.23183 XCJC=1 +FC=0.8 CJS=0 VJS=0.75 MJS=0.5 +TR=1e-07 PTF=0 KF=0 AF=1

wird zu:

.model MJL4281A NPN( IS=9.94641e-11 BF=191.836 NF=1.11524 VAF=24.7449 IKF=5.75399 ISE=6.4507e-12 NE=3.39407 BR=4.35182 NR=1.1764 VAR=4.25175 IKR=6.61715 ISC=3.89999e-13 NC=3.99 RB=4.37715 IRB=0.00966879 RBM=1e-15 RE=0.00608852 RC=0.0434329 XTB=0.661303 XTI=1.00355 EG=1.05 CJE=9.04931e-09 VJE=0.99 MJE=0.844324 TF=1.6665e-09 XTF=1000 VTF=17023.9 ITF=152.472 CJC=8.80163e-10 VJC=0.942802 MJC=0.23183 XCJC=1 FC=0.8 CJS=0 VJS=0.75 MJS=0.5 TR=1e-07 PTF=0 KF=0 AF=1 Vceo=350 Icrating=15000m mfg=Onsemi)

mfg setzt den Hersteller fest. Die "+" sind meines Wissens egal.


Grüße Stefan

Hallo danke erstmal. ich arbeite sonst mit orcad 9.1.
deshalb ist das ungewohnt für mich.

irgendwie funktioniert das nicht.
also ich öffne ltspice gehe weiter auf new schematics dann auf ??? kannst du mir das bitte nochmal detailliert erläutern? ich muß nachfolgendes model einbiniden.(.lib datei) vielen dank.
meine mail nataliyaschuldig@yahoo.de

mfg nataliya


.SUBCKT MAX1666V 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20
*****************
RSHRT 5 6 1m
VG G1 9 0V
VRG1 V1 G1 1V
VRG2 V5 G1 0.5V
********
*VSRC > VB3P+1V & All cells>1.5V
EB1P S1 G1 8 G1 1
EB2P S2 G1 7 8 1
EB3P S3 G1 6 7 1
DBP1 S4 S1 DC
DBP2 S4 S2 DC
DBP3 S4 S3 DC
RBP1 S4 S5 10K
VBP1 S5 G1 1.6V
********
EB3P1 S11 G1 VALUE={V(6,G1)+1}
DON4 S12 S6 DC
GON1 G1 S12 1 S11 10M
DON2 G1 S12 DC
CON1 S6 G1 1N
RON S6 G1 0.10MEG
DON1 S6 S7 DC
VON1 S7 G1 1V
GON2 G1 S8 S6 S13 1M
VINIT S13 G1 PULSE(1.1 0.1 1U 1U 1U 1K 1.1K)
DON5 G1 S8 DC
DON3 S8 S6 DC
MON1 S6 S10 G1 G1 MOSN W=1M L=5U
GON3 G1 S10 S5 S4 10M
DON6 G1 S10 DC
DON7 S10 S14 DC
VON2 S14 G1 5V
MON2 S8 S9 G1 G1 MOSN W=1M L=5U
**UVLO SIGNAL FEEDBACK**
EON2 S9A G1 UVF G1 3.3
RON1 S9 S9A 10K
CON2 S9 G1 0.5N
CON3 S8 G1 100P
*****************
*VCC
ELIM2 C2 G1 6 G1 1
GEA2 G1 C3 C1 19 10M
REA2 C3 G1 8K
DCC1 C3 C2 DC
QCC1 6 C3 C4 QN
RO1 C4 19 400
VBG2 C1 G1 3.34V
DCC2 C3 C6 DC
VLIM2 C6 G1 6.6V
CC1 C3 G1 10P
MVCC C3 C8 G1 G1 MOSN W=1M L=5U
EVCC1 C8 G1 S7 S6 5
*VCC > 2.85V, VOK SIG
GVCC1 G1 C7 VALUE={(V(19,G1)-2.85)*1M}
DVCC1 G1 C7 DA
DVCC2 C7 S7 DA
CVCC1 C7 G1 100P
CVCC2 19 G1 100P
DVCC3 19 1 DB
*****************
*REFERENCE OUT
VBG1 R1 G1 1.221V
ELIM1 R2 G1 19 G1 1V
GEA1 G1 R3 R1 R5 0.156
REA1 R3 G1 10K
DRF1 R3 R2 DC
QREF R2 R3 R4 QN
RREF R4 R5 6.0K
MREF R3 R8 G1 G1 MOSN W=1M L=5U
VREF R5 18 0V
EREF R8 G1 V3 O2 1
*********
*REF > 1.1V
GRF1 G1 R7 VALUE={(V(18,G1)-1.1)*10M}
RRF1 R7 G1 1MEG
DRF2 G1 R7 DC
DRF3 R7 V1 DC
CRF1 R7 G1 10P
*****************
*OVER DISCHARGE
*MEM BIT
DOD1 G1 D1 DC
COD1 D1 G1 100P
GOD1 G1 D1 D1 V5 10M
DOD2 D1 V1 DC
ROD2 D1 G1 1MEG
MOD1 D1 D2 G1 G1 MOSN W=1M L=5U
ROD1 D2 G1 100K
********
*OD CHECK
GOD2 G1 D3 VALUE={(V(10,9)-0.3)*10M+V(D3,G1)*10U}
DOD3 G1 D3 DC
DOD4 D3 V1 DC
COD2 D3 G1 10P
MOD2 D3 D9 G1 G1 MOSN W=1M L=5U
COD4 D9 G1 200P
ROD6 D10 D9 1K
EOD3 D10 G1 D1 V5 5
********
*2.4mS AND OD SET
EOD1 D4 G1 D3 G1 1
ROD3 D4 D6 100K
DOD5 D5 D4 DC
ROD4 D5 D6 10
COD3 D6 G1 34.62N
********
GOD3 G1 D7 D6 V5 10M
DOD7 G1 D7 DC
DOD6 D7 V1 DC
ROD5 D7 G1 1MEG
EOD2 D8 G1 D7 G1 1
DOD8 D8 D1 DC
********
*550mS AND RESET
EOD4 D11 G1 D1 G1 1
ROD7 D11 D13 1MEG
DOD9 D12 D11 DC
ROD8 D12 D13 0.5K
COD5 D13 G1 739N
********
GOD4 G1 D14 VALUE={(V(D13,V5)*10M)+(V(D14,V5)*0.5M)}
DOD10 G1 D14 DC
DOD11 D14 V1 DC
COD6 D14 V1 100P
EOD5 D2 G1 D14 G1 3
*****************
*****************
*OVER CHARGE
*MEM BIT
DOC1 G1 H1 DC
COC1 H1 G1 100P
GOC1 G1 H1 H1 V5 10M
DOC2 H1 V1 DC
ROC2 H1 G1 1MEG
MOC1 H1 H2 G1 G1 MOSN W=1M L=5U
ROC1 H2 G1 100K
********
*OC CHECK
GOC2 G1 H3 VALUE={(V(9,10)-0.2)*10M+V(H3,G1)*10U}
DOC3 G1 H3 DC
DOC4 H3 V1 DC
COC2 H3 G1 10P
MOC2 H3 H9 G1 G1 MOSN W=1M L=5U
COC4 H9 G1 200P
ROC6 H10 H9 1K
EOC3 H10 G1 H1 V5 5
********
*2.4mS AND OC SET
EOC1 H4 G1 H3 G1 1
ROC3 H4 H6 100K
DOC5 H5 H4 DC
ROC4 H5 H6 10
COC3 H6 G1 34.62N
********
GOC3 G1 H7 H6 V5 10M
DOC7 G1 H7 DC
DOC6 H7 V1 DC
ROC5 H7 G1 1MEG
EOC2 H8 G1 H7 G1 1
DOC8 H8 H1 DC
********
*550mS AND RESET
EOC4 H11 G1 H1 G1 1
ROC7 H11 H13 1MEG
DOC9 H12 H11 DC
ROC8 H12 H13 0.5K
COC5 H13 G1 739N
********
GOC4 G1 H14 VALUE={(V(H13,V5)*10M)+(V(H14,V5)*0.5M)}
DOC10 G1 H14 DC
DOC11 H14 V1 DC
COC6 H14 V1 100P
EOC5 H2 G1 H14 G1 3
*****************
*OSC
VRG3 V3 G1 3V
ROS1 V3 O1 100K
COS1 O1 G1 727N
ROS2 O1 O4 1.33K
MOS2 O4 O2 G2 G2 MOSN W=500U L=5U
COS3 O4 G1 100P
GOS1 G1 O2 VALUE={(V(O1,G1)-2)*12M+V(O2,G1)*8M}
DOS1 G1 O2 DC
DOS2 O2 V3 DC
COS2 O2 G1 1N
EOS1 O3 G1 V1 C7 3
MOS1 O1 O3 G1 G1 MOSN W=1M L=5U
VG2 G2 G1 -0.2V
*INIT
VINIT2 INT1 G1 PULSE(0 3V 1U 1U 1U 1K 1.1K)
DINIT1 O1 INT1 DA
********
*CLK FOR REF SAMPLE
GOS3 G1 O5 VALUE={V(O1,V5)*10M}
DOS3 G1 O5 DC
DOS4 O5 V1 DC
COS4 O5 G1 1N
ROS3 O5 G1 1MEG
*AND & DELAY
EOS3 O7 G1 O2 G1 1
EOS4 O6 G1 O5 G1 1
DOS5 O8 O7 DC
DOS6 O8 O6 DC
ROS4 V1 O8 100K
COS5 O8 G1 2N
********
*CLK FOR RS_FF
ECLK1 CL1 G1 R7 G1 2
RCLK1 CL1 CL2 10K
TCLK1 CL2 G1 CL3 G1 ZO=10K TD=2.48M
RCLK2 CL3 G1 10K
ECLK2 CL4 G1 R7 G1 1
ECLK3 CL5 G1 CL3 G1 1
DCLK1 CLK CL4 DC
DCLK2 CLK CL5 DC
RCLK3 V1 CLK 100K
*****************
*EXT REFS
VOV A1 G1 4V
EOV A2 A1 17 G1 327.6M
VUV A3 G1 2V
EUV A4 A3 16 G1 819M
EMM A5 G1 15 G1 409.5M
RS15 15 G1 1G
RS16 16 G1 1G
RS17 17 G1 1G
*****
MR1 A2 A6 A7 G1 MOSN W=1M L=5U
CR1 A7 G1 10N
ER1 A6 G1 O8 G1 6
MR2 A4 A6 A8 G1 MOSN W=1M L=5U
CR2 A8 G1 10N
MR3 A5 A6 A9 G1 MOSN W=1M L=5U
CR3 A9 G1 10N
*****************
*UNDER VOLTAGE
DUV1 UV1 S1 DA
DUV2 UV1 S2 DA
DUV3 UV1 S3 DA
VRG4 V4 G1 4V
RUV1 V4 UV1 100K
********
GUF2 G1 UF3 VALUE={(V(A8,UV1)*10M)+(V(UF3,G1)*1M)}
CUF2 UF3 G1 100P
DUF3 G1 UF3 DC
DUF4 UF3 V1 DC
XUVF UF3 CLK UVF G1 V2 RS_FF
********
*WARNING
GWF1 G1 WF1 VALUE={((V(A8,UV1)+0.1)*10M)+(V(WF1,G1)*2M)}
DWF1 G1 WF1 DC
DWF2 WF1 V1 DC
CWF1 WF1 G1 100P
XWF WF1 CLK UWF G1 V2 RS_FF
*****************
*OVER VOLTAGE
DOV1 S1 OV1 DA
DOV2 S2 OV1 DA
DOV3 S3 OV1 DA
ROV1 OV1 G1 100K
********
GOVF1 G1 OF1 VALUE={(V(OV1,A7)*10M)+(V(OF1,G1)*2M)}
DOVF1 G1 OF1 DC
DOVF2 OF1 V1 DC
COVF1 OF1 G1 100P
XOVF OF1 CLK OVF G1 V2 RS_FF
*****************
*MISS MATCH
EMM1 MM1 G1 VALUE={SQRT(V(S1,S2)**2)}
EMM2 MM2 G1 VALUE={SQRT(V(S2,S3)**2)}
EMM3 MM3 G1 VALUE={SQRT(V(S1,S3)**2)}
DMM1 MM1 MM4 DA
DMM2 MM2 MM4 DA
DMM3 MM3 MM4 DA
RMM1 MM4 MM6 100K
VMM1 MM6 G1 -1M
********
GMM1 G1 MM5 VALUE={V(MM4,A9)*10M+V(MM5,G1)*10U}
DMM4 G1 MM5 DC
DMM5 MM5 V1 DC
CMM1 MM5 G1 100P
RMM2 MM5 G1 1MEG
XMMF MM5 CLK MMF G1 V2 RS_FF
*****************
*INITIALIZE
VINIT3 V2 G1 PULSE(0 1V 1U 1U 1U 1K 1.1K)
*EVINT V2 G1 VALUE={V(VX,G1)*V(C7,G1)}
.IC V(MM5)=0 V(OF1)=0
.IC V(UF3)=0 V(WF1)=0
.IC V(D1)=0 V(H1)=0 V(A7)=4.5
*****************
*DSI
VRIN VR2 10 2V
GDS1 G1 DS1 VALUE={V(11,VR2)*1M+V(DS1,G1)*1.54M}
CDS1 G1 DS1 1N
DDS1 G1 DS1 DC
DDS2 DS1 V1 DC
IDSI 11 10 1U
*****************
*CGI
GCG1 G1 CG1 VALUE={V(12,VR2)*1M+V(CG1,G1)*1.54M}
CCG1 G1 CG1 1N
DCG1 G1 CG1 DC
DCG2 CG1 V1 DC
ICGI 12 10 1U
*****************
*DSOB
DDS3 DS1 DS2 DC
DDS4 UVF DS2 DC
DDS5 MMF DS2 DC
DDS6 D1 DS2 DC
RDS1 DS2 G1 1MEG
XDSOB 1 G1 DS2 2 C7 HPDRV
*****************
*CGOB
DCG3 CG1 CG2 DC
DCG4 OVF CG2 DC
DCG5 MMF CG2 DC
DCG6 UVF CG2 DC
DCG7 H1 CG2 DC
RCG1 CG2 G1 1MEG
XCGOB 1 G1 CG2 4 C7 HPDRV
*****************
*TKOB
DTK1 CG1 TK1 DC
DTK2 OVF TK1 DC
DTK3 MMF TK1 DC
RTK1 TK1 G1 1MEG
***
QTK1 3 TK2 1 QP
RTK3 3 G1 190K
RTK2 1 TK2 5.52K
RTK4 TK2 TK3 2.76K
MTK1 TK3 TK6 TK4 G1 MOSN W=50U L=5U
RTK5 TK4 G1 2.76K
RTK6 TK6 TK5 10K
ETK1 TK5 G1 VALUE={V(TK1,G1)*V(C7,G1)*3.3}
*****************
*UVOB
DUVO1 MMF UVO1 DC
DUVO2 UVF UVO1 DC
RUVO1 UVO1 G1 1MEG
MUVO1 20 UVO2 UVO3 G1 MOSN W=50U L=5U
GUVO1 UVO3 G1 S6 G1 30U
DUVO3 G1 UVO3 DC
EUVO1 UVO2 G1 VALUE={V(V1,UVO1)*V(C7,G1)*3.3}
CUVO1 20 G1 15P
*****************
*WRNB
DWR1 OVF WR1 DC
DWR2 UWF WR1 DC
DWR3 UVF WR1 DC
RWR1 WR1 G1 1MEG
********
MWR1 14 WR2 19 19 MOSP1 W=30U L=5U
MWR2 14 WR2 G1 G1 MOSN1 W=42U L=5U
CWR1 14 G1 15P
EWR1 WR2 G1 VALUE={V(WR1,G1)*V(C7,G1)*3.3}
*****************
*PKF
MPK1 13 PK2 19 19 MOSP1 W=30U L=5U
MPK2 13 PK2 G1 G1 MOSN1 W=84U L=5U
CPK1 13 G1 15P
EPK1 PK2 G1 VALUE={V(MMF,G1)*V(C7,G1)*3.3}
*****************
*ISUP
ISUP 6 9 1U
ISUP2 1 9 2U
GSUP 6 9 S6 G1 29U
*******************************************************
.MODEL QN NPN(IS=16E-15 BF=100)
.MODEL QP PNP(IS=16E-15 BF=10.5)
.MODEL MOSN NMOS(VTO=0.7 KP=88E-4)
.MODEL MOSP PMOS(VTO=-0.7 KP=88E-4)
.MODEL MOSN1 NMOS(VTO=0.7 KP=50E-5)
.MODEL MOSP1 PMOS(VTO=-0.7 KP=50E-5)
.MODEL DA D(N=1M)
.MODEL DB D(IS=100E-14)
.MODEL DC D(N=10M)
*******************************************************
.ENDS
*******************************************************
.SUBCKT HPDRV SRC G1 IN OUT ON
VRG V1 G1 1V
R1 SRC HP1 5.52K
Q1 OUT HP1 SRC QP
M1 OUT HP4 HP3 G1 MOSN W=50U L=5U
C2 HP3 G1 10P
EIN2 HP4 G1 V1 IN 4.6
GBIAS HP3 G1 ON G1 30U
D1 G1 HP3 DA
D2 HP3 SRC DA
R2 HP1 HP5 1.38K
M2 HP5 HP6 HP7 G1 MOSN W=1000U L=5U
R3 HP7 G1 1.84K
R4 HP6 G1 10K
D3 G1 HP6 DA
C1 HP6 HP8 0.7N
EIN1 HP8 G1 IN G1 3.6
CL OUT G1 5P
***********************************
.MODEL QP PNP(IS=16E-15 BF=14)
.MODEL MOSN NMOS(VTO=1.0 KP=88E-4)
.MODEL DA D(N=1M)
.ENDS
*******************************************************
.SUBCKT RS_FF IN CLK OUT G1 RST
VRG1 V1 G1 1V
VRG2 V5 G1 0.5V
GFF1 G1 FF1 FF1 V5 10M
DFF1 G1 FF1 DC
DFF2 FF1 V1 DC
CFF1 FF1 G1 100P
RFF1 FF1 G1 1MEG
*********
DINIT1 FF1 RST DA
*********
*TIMER, SET & RESET
EEF1 FF2 G1 IN G1 1
DFF3 FF3 FF2 DC
RFF2 FF3 FF2 1MEG
CFF2 FF3 G1 354.7N
****
GFF2 G1 FF4 VALUE={V(FF3,V5)*1M+V(FF4,G1)*30U}
DFF4 G1 FF4 DC
DFF5 FF4 V1 DC
CFF3 FF4 G1 100P
****
DFF6 FF2 FF5 DC
RFF3 FF2 FF5 1MEG
CFF4 FF5 G1 322N
****
GFF3 G1 FF6 VALUE={V(FF5,V5)*1M+V(FF6,G1)*30U}
DFF7 G1 FF6 DC
DFF8 FF6 V1 DC
CFF5 FF6 G1 100P
****
EFF2 FF7 G1 FF6 G1 1
EFF3 FF8 G1 FF4 G1 1
DFF9 FF9 FF7 DC
DFF10 FF8 FF9 DC
CFF6 FF9 G1 10N
*********
EFF4 FF10 G1 FF9 G1 1
EFF5 FF11 G1 CLK G1 2
MFF1 FF10 FF11 FF1 G1 MOSN W=0.2M L=5U
VOUT FF1 OUT 0V
*******************************************************
.MODEL MOSN NMOS(VTO=0.7 KP=88E-4)
.MODEL DA D(N=1M)
.MODEL DB D(IS=100E-14)
.MODEL DC D(N=10M)
*******************************************************
.ENDS

Dein Model ist ja etwas ausgefallener.
Bei meinem Model habe ich mich auf diskrete Komponenten beschränkt. So komplexe Dinger habe ich bisher nicht einbinden müssen, es gibt aber eine Anleitung in der Hilfe im Programm. Zunächst F1 für "Hilfe" drücken, dann auf FAQ kicken und Third-Party-Models auswählen. Da ist beschrieben, wie man sowas einbindet. Ich hatte mal auch ein sehr gutes Tutorial für LTSpice, leider ist mir das abhandengekommen....

Ich hoffe, dir hilft das weiter.

Gruß Stefan

Hallo Stefan,

meinst Du so etwas: "Manual_scad3.pdf"? Das habe ich hier, 990KB, 290 Seiten.

Hallo Timo,

ich meinte eine ca. 100-seitige Anleitung, die ich leider nur noch als Ausdruck besitze.
Es wäre aber sehr nett, wenn du mir dein Manual zukommen lassen könntest. Email von mir hast du glaube ich.

Edit:
Habe es gefunden: Link

Grüße, Stefan

Ich habe ja fast keine Ahnung davon, aber ich glaube mich dumpf zu errinnern, da war ein Unterschied zwischen ein "Model" einbauen und ein "Subcircuit" -SUBCTK einbauen. Kann es sein, das dort ein Teil des Problemes liegt?

da war ein Unterschied zwischen ein "Model" einbauen und ein "Subcircuit" -SUBCTK einbauen

Exakt. Das mit dem SUBCTK habe ich aber wie gesagt noch nicht ausprobiert. Jedoch ist in der Hilfe beschrieben wie es gehen sollte.

Hallo,

gibt es eine Möglichkeit, aus Datenblättern LT-Models zu gewinnen?

Gibt es eine Art Model-Sammlung? Kenne nur die der LTspice-Yahoo-Group.

Grüße
URI